// POV-Ray 3.6 Scene Description file
// File:   Toric lens surface 2.pov
// Descr.: Toric lens surface explained as a "cap" cut off a torus
// Date:   2011-07-15
// Author: HHahn
//
//---------------------

#include "colors.inc"

camera
{
  location <0, .1, -25>
  look_at 0
  angle 30
}

//   background { color Gray95 }  // Background colour

light_source { <-1000, 3000, -4000> White }

//---------------------

#declare RING_COLOUR = rgb <1.3, 1.3, 2.0>;
#declare BOX_COLOUR  = rgb <1.3, 1.8, 2.0>;

#declare RING = torus
{
  1.2, 1                  // Major and minor radius
  pigment { RING_COLOUR }
  rotate -90*x            // View torus from from the top
}

#declare BOX1 = box
{
  < -2.75, -3, -3>,       // Near-lower-left corner
  <  1.9,   3,  3>        // Far-upper-right corner
  pigment { BOX_COLOUR }
}

#declare BOX2 = box
{
  < 2.75, -3, -3>,        // Near-lower-left corner
  < 1.9,   3,  3>         // Far-upper-right corner
  pigment { BOX_COLOUR }
}

union
{
  intersection
  {
    object { RING }
    object { BOX1 }
    
  }

  intersection
  {
    object { RING }
    object { BOX2 }
    translate 0.65*x       // Move cap slightly away from torus
  }

  rotate z*25
  rotate y*20
  rotate -x*15
  scale <2, 2, 2>
  translate -x*1.7
  translate -y*0.15
}